
实验目的与要求
（1） 熟悉分支、循环程序的结构及控制方法，掌握分支、循环程序的调试方法；
（2） 加深对转移指令及一些常用的汇编指令的理解；
（3） 加深对常用DOS功能调用指令的理解，进一步熟悉TD的使用。
[bookmark: _Toc447223777][bookmark: _GoBack]实验内容
设计实现一个学生成绩查询的程序。
1、实验背景
在以BUF为首址的字节数据存储区中，存放着n个学生的课程成绩表（百分制），每个学生的相关信息包括：姓名（占10个字节，结束符为数值0），语文成绩（1个字节），数学成绩（1个字节），英语成绩（1个字节），平均成绩（1个字节）。
例如：
N    EQU   1000
BUF  DB  ‘zhangsan’,0,0   ;学生姓名，不足10个字节的部分用0填充
DB    100, 85, 80,？   ; 平均成绩还未计算
     DB  ‘lisi’,6 DUP(0)
DB    80, 100, 70,?
DB   N-3 DUP( ‘TempValue’,0,80,90,95,?) ;除了3个已经具体定义了学生信息的成绩表以外，其他学生的信息暂时假定为一样的。
     DB  ‘wangwu’，0，0，0，0     
DB    85, 85,  100, ?

2、功能一：提示并输入学生姓名
（1）使用9号DOS系统功能调用，提示用户输入学生姓名。
（2）使用10号DOS系统功能调用，输入学生姓名。输入的姓名字符串放在以in_name为首址的存储区中。
（3）若只是输入了回车，则回到“(1)”处重新提示与输入；若仅仅输入字符q，则程序退出,否则，准备进入下一步处理。

3、功能二：以学生姓名查询有无该学生
（1）使用循环程序结构，在成绩表中查找该学生。
（2）若未找到，就提示用户该学生不存在，并回到“功能一（1）”的位置，提示并重新输入姓名。
（3）若找到，则将该学生课程成绩表的起始偏移地址保存到POIN字变量中。
提示：字符串比较时，当采用输入串的长度作为循环次数时，若因循环次数减为0而终止循环，则还要去判断成绩表中名字串的下一个字符是否是结束符0，若是，才能确定找到了。

4、功能三：计算所有学生的平均成绩
使用算数运算相关指令计算并保存每一个学生的平均成绩。
平均成绩计算公式：(A*2+B+C/2)/3.5，即将语文成绩A乘以权重2、英语成绩C除以权重2后，与数学成绩B一起求和，再计算该生的平均成绩。要求避免溢出。
提示：使用循环程序结构，注意寻址方式的灵活使用。把小数3.5转换成分数后再运算避免使用浮点数指令。

5、功能四：将功能二查到的学生的平均成绩进行等级判断，并显示判断结果。
（1）平均成绩等级显示方式：若平均成绩大于等于90分，显示“A”；大于等于80分，显示“B”；大于等于70分，显示“C”；大于等于60分，显示“D”；小于60分，显示“F”。 
提示：使用分支程序结构，采用2号DOS系统功能调用显示结果。
（2）使用转移指令回到“功能一（1）”处（提示并输入姓名）。

6、思考与选做功能
（1）对输入的姓名进行合法性检查，比如：是否存在大小写字母之外的字符，等等；若存在非法的输入情形，则提示之后重新输入。
（2）对BUF中预先定义的课程成绩表中的所有成绩项进行合法性检查，判断是否符合实际（如超过100分等），不符合则提示并退出程序。预先定义的学生姓名中，如果有重名如何处理？
（3）除了显示平均成绩的等级外，还将平均成绩同时显示。
（4）由于有些课程体系中，成绩的满分可能会达到300分，此时，成绩项的定义必须采用字类型，那么，如何改造程序呢？采用数据结构来定义BUF存储区是否会更好？
[bookmark: _Toc447223778]实验过程
[bookmark: _Toc447223779]任务1
[bookmark: _Toc418458599][bookmark: _Toc447223780]设计思想及存储单元分配
根据要求，用10号功能调用把输入的姓名字符串存放在数据段中，先判断输入的第一个字符是不是回车，如果是，重新输入，如果不是，找到回车的地址，重新赋值为0，再判断是否仅输入了q，如果是，退出，否则继续。
把输入的姓名与已经在数据段中预先定义的学生姓名对比，有两层循环，第一层负责遍历每个学生，每经过一个学生，基址寄存器的值增加14（一个学生的姓名和成绩占据的空间总大小为14个字节），第二层循环负责判断两个姓名字符串是否相等，一个字符一个字符比较，遇到不相同的字符，跳出本层循环，继续与下一个学生对比，如果比较了10次，每个字符都相同，即两个字符串相同，找到了学生，保存此时基址寄存器的值，就是这个学生姓名的起始地址；遍历了所有学生，仍没有找到相同的姓名，说明该学生不存在，回到开始，把需要保存姓名字符串的内存空间全部清零，改变过的寄存器清零，然后输入新的姓名，再次查找。
计算平均成绩，从第一个学生开始，按照规则，第一个成绩乘2，放到寄存器中，第二个成绩不变，加到第一个成绩保存的寄存器中，第三个成绩除以2，加到寄存器中，再把总成绩乘2，除以7。即得到平均成绩，保存到每个学生数据部分的第14个字节中，再偏移地址加14，计算下一学生平均成绩，直到计算完成所有学生。
判断等级，从POIN处读取对应的学生地址，从第14个字节读取平均成绩，依次与90,80,70,60比较，得出等级，输出等级。
[bookmark: _Toc447223781]流程图

[bookmark: _Toc447223782]源程序

.386
STACK SEGMENT USE16 STACK
	DB 200 DUP(0)
STACK ENDS
DATA SEGMENT USE16
N EQU 10
BNB DB 7
BUF DB 'ZHANGSAN',0,0
	DB 100,85,80,?
	DB 'LISI',6 DUP(0)
	DB 80,100,70,?
	DB N-3 DUP('TempValue',0,80,90,95,?)
	DB 'WANGWU',0,0,0,0
	DB 85,85,100,?
POIN DW 0
OUPUT DB 0AH,0DH,'Please input student name:$'
UNFND DB 0AH,0DH,'Student not found!$'
INAME DB 10
	DB ?
NAMM	DB 10 DUP(0)
DATA ENDS

CODE SEGMENT USE16
		ASSUME CS:CODE,DS:DATA,SS:STACK
START:	MOV AX,DATA
		MOV DS,AX
INPUT:	MOV CX,10
		MOV BX,0
LLL:	MOV NAMM[BX],0
		INC BX
		DEC CX
		JNZ LLL
		MOV ECX,0
		MOV EBX,0
		MOV EDX,0
		MOV EAX,0
		LEA DX,OUPUT;功能1提示并输入学生姓名
		MOV AH,9
			INT 21H
		LEA DX,INAME
		MOV AH,10
			INT 21H
		CMP NAMM,13;输入了回车
		JZ INPUT
		MOV CL,INAME+1
		MOV NAMM[ECX],0
		CMP NAMM,'q';输入了q
		JZ EXIT

		MOV CX,N;功能2查找学生
		MOV EBX,0
LOOP2:	MOV ESI,0;0~10,循环把姓名中的每个字符放入AL
LOOP1:	MOV AL,NAMM[ESI]
		CMP AL,BUF[EBX][ESI]
		JNZ LOOP3
		INC SI
		CMP SI,10
		JZ SAVEP;保存起始地址
		JMP LOOP1
LOOP3:	ADD EBX,14
		DEC CX
		CMP CX,0
		JZ NFD;未找到学生结束循环
		JMP LOOP2
NFD:	LEA DX,UNFND
		MOV AH,9
			INT 21H
		JMP INPUT;回到功能1
SAVEP:	MOV POIN,BX
		MOV EBX,0
		ADD POIN,OFFSET BUF
		
		MOV ESI,OFFSET BUF;功能3计算平均成绩
		MOV CX,N
		MOV EAX,0
GNT:	MOV AL,BYTE PTR 10[ESI]
		SAL EAX,1
		MOV EDX,EAX
		MOV EAX,0
		MOV AL,BYTE PTR 11[ESI]
		ADD EDX,EAX
		MOV EAX,0
		MOV AL,BYTE PTR 12[ESI]
		SAR EAX,1
		ADD EDX,EAX
		SAL EDX,1
		MOV EAX,EDX
		MOV EDX,0
		DIV BNB
		MOV 13[ESI],AL
		ADD ESI,14
		MOV EAX,0
		DEC CX
		JNZ GNT

		MOV DL,10;功能4判定等级
		MOV AH,2
		INT 21H
		MOV DL,13
		MOV AH,2
		INT 21H
		MOV EAX,0
		MOV AX,POIN
		MOV SI,AX
		MOV EAX,0
		MOV AL,13[SI]
		CMP AL,90
		JNS PUTA
		CMP AL,80
		JNS PUTB
		CMP AL,70
		JNS PUTC
		CMP AL,60
		JNS PUTD
		JMP PUTE
PUTA:	MOV DL,'A'
		MOV AH,2
		INT 21H
		JMP INPUT
PUTB:	MOV DL,'B'
		MOV AH,2
		INT 21H
		JMP INPUT
PUTC:	MOV DL,'C'
		MOV AH,2
		INT 21H
		JMP INPUT
PUTD:	MOV DL,'D'
		MOV AH,2
		INT 21H
		JMP INPUT
PUTE:	MOV DL,'E'
		MOV AH,2
		INT 21H
		JMP INPUT

EXIT:		MOV AH,4CH
			INT 21H
CODE ENDS
	END START
		
	
[bookmark: _Toc447223783]实验步骤
（1） 写好代码，根据编译器的提示信息修改
（2） 连接好之后，运行程序看是否正确
（3） 调试，单步执行，根据运行情况与期望情况的差别修改代码，不断重复，直到工作与预期相同
[bookmark: _Toc447223784]实验记录
1、实验环境条件：P3 1GHz，256M内存；WINDOWS 2000命令行窗口；EDIT.EXE 2.0；MASM.EXE  6.0； LINK.EXE 5.2; TD.EXE 5.0。
2、实验结果观察
[image: ]
（1） 执行程序后，输入”ZHANGSAN”，显示A
（2） 输入“LISI”，显示B
（3） 输入“WANGWU”，显示B
（4） 输入不存在的学生，提示未找到
（5） 只输入回车，再次提示输入姓名
（6） 输入q，程序退出
程序工作情况与预期相同。
查看内部数据：[image: ]
（7） [image: ]ZHANGSAN平均成绩为5CH，正确
（8） [image: ]LISI平均成绩为54H，正确
（9） WANGWU平均成绩为57H，正确。

[bookmark: _Toc447223785]体会
通过上机，不仅提高了编程水平，熟悉了工具的使用，而且加深了对编写代码前画流程图重要性的理解。
当一个程序的任务比较复杂，使用比较多的寄存器时，最好在使用寄存器时把每个寄存器的功能标注清楚。
程序遇到bug时不能想当然只看代码，要耐心调试，一条指令一条指令看下去才能找到问题所在。
这次实验还遇到一个奇怪的问题，就是比较姓名时，第一次无论输什么都能比较，第二次第三次可能会有问题，检查了很久，比较的算法是没有问题的，最后才发现问题出在姓名输入上，第一次输入姓名，比较完成以后，没有及时把保存输入内容的内存部分清空，导致后面的姓名有问题，不是输入的姓名，后面还有之前的输入的遗留。所以，在需要多次重复的工作时，一定要确保之前的操作对后面的操作没有影响。
这次实验任务比较重，主要是有两层循环，比较容易出错，需要思路非常清晰才可以，尤其是跳转的地方，更要小心，避免出错。
[bookmark: _Toc20296][bookmark: _Toc447223786]参考文献
[1] 王元珍,曹忠升,韩宗芬.80X86汇编语言程序设计.第1版.武汉:华中科技大学,2005年4月.1-93

